     FALSE = 0
     TRUE = 1
     FILENAME = FIELD(@COMMAND,' ',2)
     IF FILENAME EQ ''
     THEN
        PROMPT ''
        PRINT 'Enter filename to create F# DICT items in: ':
        INPUT FILENAME
        IF FILENAME EQ '' THEN STOP '*NOTHING DONE'
     END
     OPEN 'DICT',FILENAME TO FILE ELSE STOP 'Unable to open ':FILENAME
     EXECUTE 'SELECT DICT ':FILENAME:' BY LOC'
     READNEXT KEY ELSE STOP 'DICT ':FILENAME:' is empty.'
     LOOP
        READ RECORD FROM FILE,KEY ELSE STOP 'Unable to read ':KEY
        IF (RECORD<1>[1,1] EQ 'I') AND (KEY[1,1] EQ 'F') AND NUM(KEY[2,99]) AND (LEN(KEY) GT 1)
        THEN PRINT 'WARNING: An I-descripter exists under the name ':KEY
        ELSE
           FKEY = TRIM(RECORD<2>)
           IF NUM(FKEY) AND (FKEY NE '') AND (RECORD<1>[1,1] EQ 'D')
           THEN
              FKEY = 'F':FKEY
              OKAY = FALSE
              READ TEST.RECORD FROM FILE,FKEY ELSE OKAY = TRUE
              IF OKAY
              THEN
                 IF RECORD<4> EQ '' THEN RECORD<4> = KEY
                 WRITE RECORD TO FILE,FKEY
                 PRINT FKEY:' created.'
              END
              ELSE
                 PRINT FKEY:' already exists.'
              END
           END
        END
        READNEXT KEY ELSE STOP '*DONE'
     REPEAT
  END
