PROGRAM Install
***
* Program to install eMail in any INFORMATION account.
***
LastUpdated... = "Rev: 09:37 03AUG90 ANDREW <KSF.V2>EMAIL 161 Z <KSF.V2>EMAIL>BP>EMAILINSTALL"
     OPEN "","VOC" TO VocFile ELSE STOP "Unable to open VOC file."
     VocRec = "V":@FM:"*EMAIL*SHOWREV":@FM:"IB"
     WRITE VocRec TO VocFile, "SHOWREV"
     CALL SHOWREV(LastUpdated...)
     CRT "Installing eMail in ":@WHO

     Origin = "EMAIL"

     FileList = ""
     FileList<-1> = "EMAIL.DATA"
     FileList<-1> = "EMAIL.HELP"
     FileList<-1> = "EMAIL.LOG"
     FileList<-1> = "EMAIL.TABLE"
     FileList<-1> = "EMAIL.USERS"

     More = 1
     LOOP WHILE More
        REMOVE Item FROM FileList SETTING More
        VocRec = "F"
        VocRec<2> = Origin:">":Item
        VocRec<3> = Origin:">":"D_":Item
        WRITE VocRec TO VocFile, Item
     REPEAT

     ProgList = ""
     ProgList<-1> = "*-*EMAIL"
     ProgList<-1> = "*-*PARSEOPTIONS"
     ProgList<-1> = "*-*RESOLVEUSERLIST"
     ProgList<-1> = "*-*OPEN"
     ProgList<-1> = "*-*TOLCSENT"
     ProgList<-1> = "*-*EDITOR"
     ProgList<-1> = "*-*SENDEMAIL"
     ProgList<-1> = "*-*CENTER"
     ProgList<-1> = "*-*READU"
     ProgList<-1> = "*-*MAPGROUP"
     More = 1
     LOOP WHILE More
        REMOVE Item FROM ProgList SETTING More
        IF INDEX(Item,"-",1) GT 0 THEN
           Item = FIELD(Item,"-",1):Origin:FIELD(Item,"-",2)
        END
        VocRec = "V"
        VocRec<2> = Item
        VocRec<3> = "IB"
        WRITE VocRec TO VocFile, FIELD(Item,'*',3)
     REPEAT

     CRT "DONE"
     RETURN
  END